#version 3.5;

#include "colors.inc"

global_settings {
  assumed_gamma 1.0
}

#macro paddedWall (X,Y)
  merge {
  #declare J=1;
  #while (J<=Y)   
    #declare I =1;
    #while(I<=X)
      sphere {<I,J,0>,1}
      sphere {<I+.5,J+.5,-.7>,.1}
      sphere {<I+.5,J+.5, .7>,.1}
      #declare I=I+1;
    #end
  #declare J=J+1; 
  #end
  pigment {color rgb <.3,.3,.3>}
  }
#end

#declare Wall = object {paddedWall (12,10)  scale .5 }
#declare bulb =     sphere {
      <0, 0, 0> // center of sphere <X Y Z>
      0.08       // radius of sphere
      pigment { rgb <1,1,.5> }
      finish  {ambient 1}
    }
// ---------------------------------------- Camera & Lights

camera {
  location  <-0.5, 0.2, -2>
  look_at   <0.0, 2.17,  0.0>
  angle 120 
}

light_source {
  <0, 2.17, 0>            // light's position (translated below)
  color rgb <1,1,.5>      // light's color
  looks_like { bulb }
}

// ---------------------------------------- Floor
box {
  <-2, 0.05, -5>  // one corner position <X1 Y1 Z1>
  < 2, -1,  2.4>  // other corner position <X2 Y2 Z2>
  pigment {
    checker
    pigment {White}
    pigment {Black}
    translate x*-.5
    scale .8
  }
}

// ---------------------------------------- Ceiling
box {
  <-3, 3, -5>  // one corner position <X1 Y1 Z1>
  < 3, 4,  5>  // other corner position <X2 Y2 Z2>
  pigment {rgb <.8,.9,.8>}
  texture {
    pigment {color rgb <0.9, 0.9, 0.9>}       
    finish{ ambient 0 }
    scale 3
  }
}

// ---------------------------------------- Back Wall
object {Wall              translate <-2.5,-2.25,3>}

// ---------------------------------------- Left Wall
object {Wall rotate y*90  translate <-2.5,-2.25, 3.25>}

// ---------------------------------------- Right Wall
object {Wall rotate y*90  translate < 2.5,-2.25, 3.25>}

// ---------------------------------------- Cable
cylinder {
  <0,3,0>,  <0,2.25,0>,  .01
  pigment {Black}
}